我的世界CRT配方修改

无尽贪婪·伪从1.16.5-1.2.2版本开始支持CraftTweaker，本教程添加一些修改示例。

无尽工作台

删除一个配方

参数：配方输出物品。

// 移除一个无尽工作台配方---（无尽催化剂）
mods.endless.ExtremeCraftRecipe.remove(<item:endless:infinity_catalyst>);

添加一个配方

3个参数：配方id，配方输出物品，【9*9的输入物品】。输入必须是9*9 81个物品，空位使用<item:minecraft:air>。

// 为钻石添加一个无尽工作台配方

// 为钻石添加一个无尽工作台配方
val neu = <item:endless:neutronium_ingot>;
val cry = <item:endless:crystal_matrix_ingot>;
val inf = <item:endless:infinity_ingot>;
val net = <item:minecraft:nether_star>;
mods.endless.ExtremeCraftRecipe.addShaped("test_a", <item:minecraft:diamond>, [
    [cry, cry, cry, cry, cry, cry, cry, cry, cry],
    [cry, neu, neu, neu, neu, neu, neu, neu, neu],
    [cry, neu, inf, inf, inf, inf, inf, neu, cry],
    [cry, neu, inf, net, <item:minecraft:air>, net, inf, neu, cry],
    [cry, neu, inf, net, <item:endless:infinity_catalyst>, net, inf, neu, cry],
    [cry, neu, inf, net, net, net, inf, neu, cry],
    [cry, neu, inf, inf, <item:minecraft:air>, inf, inf, neu, cry],
    [cry, neu, neu, neu, neu, neu, neu, neu, neu],
    [cry, cry, cry, cry, cry, cry, cry, cry, cry]
]);

使用JSON添加一个配方

//使用json添加一个无尽配方（无尽催化剂）

<recipetype:endless:extreme_craft>.addJSONRecipe("infinity_catalyst", {
   "result": {
       "item": "endless:infinity_catalyst"
   },
   "pattern": [
       "   yyy   ",
       " yymmmyy ",
       " ymmmmmy ",
       "ymmmxmmmy",
       "ymmxzxmmy",
       "ymmmxmmmy",
       " ymmmmmy ",
       " yymmmyy ",
       "   yyy   "
   ],
   "key": {
       "x": {
         "item": "endless:neutronium_ingot"
       },
       "y": {
         "item": "minecraft:nether_star"
       },
       "z": {
         "item": "minecraft:end_stone"
       },
       "m": {
         "item": "minecraft:ender_pearl"
       }
   }
});

修改结果

中子态素压缩机

在1.4.4及以上版本奇点改动，指定奇点物品需带上nbt数据。

删除一个配方

参数：配方输出物品。通过指定奇点来删除配方，但会同时删除多个合成。

// 删除单个压缩机配方 钻石奇点
mods.endless.CompressorRecipe.remove(<item:endless:singularity_diamond>);

1.4.4版本

mods.endless.CompressorRecipe.remove(<item:endless:singularity>.withTag({type: "diamond"}));

添加一个配方

4个参数为：配方id，配方输出物品，消耗材料数量，【材料1，材料2…】。每个材料数量可超过1个。

// 添加单个压缩机配方 钻石奇点
mods.endless.CompressorRecipe.addShaped("test_b", <item:endless:singularity_diamond>, 100, [<item:minecraft:dirt>, <item:minecraft:diamond> * 2]);

1.4.4版本

mods.endless.CompressorRecipe.addShaped("test_b", <item:endless:singularity>.withTag({type: "diamond"}), 100, [<item:minecraft:dirt>, <item:minecraft:diamond> * 2]);

使用JSON添加一个配方

//使用json添加单个压缩机配方 金奇点
<recipetype:endless:neutronium>.addJSONRecipe("singularity_gold", {
   "input": {
       "item": "minecraft:stick"
   },
   "count": 1000,
   "output": {
       "item": "endless:singularity_gold"
   }
});

1.4.4版本

<recipetype:endless:neutronium>.addJSONRecipe("singularity_gold", {
    "input": {
        "item": "minecraft:stick"
    },
    "count": 100,
    "output": {
        "item": "endless:singularity",
        "nbt": "{type:gold}"
    }
});

修改结果

示例文件

链接：https://pan.baidu.com/s/1vrGlMS3FVhLi9GCUtBPlng 提取码：u96u。